#! /bin/csh -f
# Script to `configure' The Hacker Crackdown by Bruce Sterling
# $Id: configure,v 1.2 1994/01/20 13:33:29 joke Rel $
#
set default=--a4
set papersize=$default
set configdir=./config
set fontfamily=cm
set fontdir=./fonts
set srcdir=.
set package="The Hacker Crackdown by Bruce Sterling"
set edition="1.2"
#
set cp="ln -s"
set cp="cp"
#
top:
if ($#argv > 0) then
    switch ($1:q)

    case --l*:
    case --a*:
	set papersize = "$1:q"
	shift
	goto top

    case --f*:
	set fontfamily = "$2:q"
	set fontfile = "$fontdir/ps.$fontfamily"
	shift
	shift
	goto top

    default:
	goto usage
    endsw
endif
#
rm -f $srcdir/Makefile
rm -f $srcdir/crackdown.texi
rm -f $fontdir/ps.fonts
#
if ("$fontfamily" != "cm") then
    $cp $fontfile $fontdir/ps.fonts
    cpp -I$fontdir -DPOSTSCRIPT -P fonts/texinfo.foo |uniq >texinfo.tex
else
    cpp -I$fontdir -P fonts/texinfo.foo |uniq >texinfo.tex
endif
#
if ("$papersize" == "--letter") then
    $cp $configdir/crackdown.us $srcdir/crackdown.texi
    $cp $configdir/Makefile.us $srcdir/Makefile
    echo "$package [Texinfo edition $edition, $fontfamily font] \
*** configured for US letter size paper."
    goto done
endif
#
if ("$papersize" == "--a4") then
    $cp $configdir/crackdown.a4 $srcdir/crackdown.texi
    $cp $configdir/Makefile.a4 $srcdir/Makefile
    echo "$package [Texinfo edition $edition, $fontfamily font] \
*** configured for A4 paper size."
    goto done
endif
#

usage:
    echo "usage: configure --<paper-size> --font <family>"
    echo "       --a4/--letter for <paper-size>"
    echo "       --font times/palatino/bookman/etc. for <family>"
    echo ""
    echo "e.g.:  configure --a4 --font palatino"
#
done: